mirror of
https://github.com/Mbed-TLS/mbedtls.git
synced 2024-12-27 12:16:07 +00:00
a4d17b34f3
Add three package config files for mbedtls, mbedcrypto and mbedx509. Also update various project variables so the generated PC files have the required data needed without hardcoding it everywhere. This will help distros package the project following existing conventsions between a normal and -devel package that includes the headers and .pc files for pkg-config aware consumers. Fixes: #228 Signed-off-by: Bill Roberts <bill.roberts@arm.com>
28 lines
983 B
CMake
28 lines
983 B
CMake
# SPDX-License-Identifier: Apache-2.0 OR GPL-2.0-or-later
|
||
# This module provides function for joining paths
|
||
# known from most languages
|
||
#
|
||
# Copyright The Mbed TLS Contributors
|
||
#
|
||
# This script originates from:
|
||
# - https://github.com/jtojnar/cmake-snips
|
||
# Jan has provided re-licensing under Apache 2.0 and GPL 2.0+ and
|
||
# allowed for the change of Copyright.
|
||
#
|
||
# Modelled after Python’s os.path.join
|
||
# https://docs.python.org/3.7/library/os.path.html#os.path.join
|
||
# Windows not supported
|
||
function(join_paths joined_path first_path_segment)
|
||
set(temp_path "${first_path_segment}")
|
||
foreach(current_segment IN LISTS ARGN)
|
||
if(NOT ("${current_segment}" STREQUAL ""))
|
||
if(IS_ABSOLUTE "${current_segment}")
|
||
set(temp_path "${current_segment}")
|
||
else()
|
||
set(temp_path "${temp_path}/${current_segment}")
|
||
endif()
|
||
endif()
|
||
endforeach()
|
||
set(${joined_path} "${temp_path}" PARENT_SCOPE)
|
||
endfunction()
|