mirror/bazzite
1
0
Fork 0
mirror of https://github.com/ublue-os/bazzite.git synced 2025-01-01 03:21:41 +00:00
Code Issues Packages Projects Releases Wiki Activity

Container indicator for fish shell (#1337)

Browse Source 
Modified default fish shell prompt to indicate if a user is inside a container with a box icon and the container name, similar to how bash looks inside a distrobox container. Not sure if there was a better way to do this, but it works!
This commit is contained in:
v7rzlhb3xg 2024-07-07 18:51:33 -04:00 committed by GitHub
parent 60e76d04f9
commit 5a4d643612
No known key found for this signature in database
GPG Key ID: B5690EEEBB952194
1 changed files with 41 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

41
system_files/overrides/usr/share/fish/functions/fish_prompt.fish Normal file
View File

@ -0,0 +1,41 @@
function fish_prompt --description 'Default prompt with container detection'
set -l last_pipestatus $pipestatus
set -lx __fish_last_status $status # Export for __fish_print_pipestatus.
set -l normal (set_color normal)
set -q fish_color_status
or set -g fish_color_status red
set -g fish_color_user brgreen
# Color the prompt differently when we're root
set -l color_cwd $fish_color_cwd
set -l suffix '>'
if functions -q fish_is_root_user; and fish_is_root_user
if set -q fish_color_cwd_root
set color_cwd $fish_color_cwd_root
end
set suffix '#'
end
# Detect if we are in a container
if test -n "$CONTAINER_ID"
set -g prompt_host "[$CONTAINER_ID]"
set -g prefix_icon "📦 "
else
set -g prompt_host "$hostname"
set -g prefix_icon ""
end
# Write pipestatus
# If the status was carried over (if no command is issued or if `set` leaves the status untouched), don't bold it.
set -l bold_flag --bold
set -q __fish_prompt_status_generation; or set -g __fish_prompt_status_generation $status_generation
if test $__fish_prompt_status_generation = $status_generation
set bold_flag
end
set __fish_prompt_status_generation $status_generation
set -l status_color (set_color $fish_color_status)
set -l statusb_color (set_color $bold_flag $fish_color_status)
set -l prompt_status (__fish_print_pipestatus "[" "]" "|" "$status_color" "$statusb_color" $last_pipestatus)
echo -n -s $prefix_icon (set_color $fish_color_user) "$USER" $normal "@" $prompt_host' ' (set_color $color_cwd) (prompt_pwd) $normal (fish_vcs_prompt) $normal " "$prompt_status $suffix " "
end